bscv/build.gradle

buildscript {
	repositories {
		maven { url = 'https://maven.minecraftforge.net' }
		mavenCentral()
	}
	dependencies {
		classpath group: 'net.minecraftforge.gradle', name: 'ForgeGradle', version: '5.1.+', changing: true
		classpath "com.palantir.gradle.gitversion:gradle-git-version:0.13.0"
	}
}

repositories {
	maven { url = 'https://maven.fantabos.co' }
}

apply plugin: 'net.minecraftforge.gradle'
apply plugin: 'java'
apply plugin: 'eclipse'
apply plugin: 'maven-publish'
apply plugin: "com.palantir.git-version"

version          = gitVersion()
group            = 'ftbsc'
archivesBaseName = 'bscv'

def shortVersion = version.split('-')[0]

// Minecraft and Forge versions
def minecraftVersion = '1.16.5'
def forgeVersion     = '36.2.34'

project.ext { // external properties coming from gradle.properties
	deployJarDo          = getProjectProperty("deployJar.do", "false")
	deployJarTargetDir   = getProjectProperty("deployJar.targetDir", ".")
}

def getProjectProperty(String property, String fallback) { //allows for custom gradle.properties while retaining default fallback values
	return (project.hasProperty(property)) ? project.property(property) : fallback
}

java.toolchain.languageVersion = JavaLanguageVersion.of(8) // Mojang ships Java 8 to end users, so your mod should target Java 8.

println('Java: ' + System.getProperty('java.version') + ' JVM: ' + System.getProperty('java.vm.version') + '(' + System.getProperty('java.vendor') + ') Arch: ' + System.getProperty('os.arch'))

minecraft {
	mappings channel: 'official', version: minecraftVersion
	accessTransformer = file('src/main/resources/META-INF/accesstransformer.cfg')
	runs {
		client {
			workingDirectory project.file('run')

			// Recommended logging data for a userdev environment
			// The markers can be changed as needed.
			// "SCAN": For mods scan.
			// "REGISTRIES": For firing of registry events.
			// "REGISTRYDUMP": For getting the contents of all registries.
			property 'forge.logging.markers', 'REGISTRIES'
			property 'forge.logging.console.level', 'debug'

			mods {
				bscv {
					source sourceSets.main
				}
			}
		}

		data {
			workingDirectory project.file('run')

			// "SCAN": For mods scan.
			// "REGISTRIES": For firing of registry events.
			// "REGISTRYDUMP": For getting the contents of all registries.
			property 'forge.logging.markers', 'REGISTRIES'
			property 'forge.logging.console.level', 'debug'

			// Specify the modid for data generation, where to output the resulting resource, and where to look for existing resources.
			args '--mod', 'bsvc', '--all', '--output', file('src/generated/resources/'), '--existing', file('src/main/resources/')

			mods {
				bscv {
					source sourceSets.main
				}
			}
		}
	}
}

// Include resources generated by data generators.
sourceSets.main.resources { srcDir 'src/generated/resources' }

dependencies {
	minecraft "net.minecraftforge:forge:${minecraftVersion}-${forgeVersion}"
	implementation 'ftbsc:lll:0.2.1'
	implementation 'ftbsc.lll:processor:0.1.0'
	annotationProcessor 'com.squareup:javapoet:1.13.0'
	annotationProcessor 'ftbsc:lll:0.2.1'
	annotationProcessor 'ftbsc.lll:processor:0.1.0'
}

jar {
	archiveName = "${jar.baseName}-${shortVersion}.${jar.extension}"
	manifest {
		attributes([
			"Specification-Title": "bscv",
			"Specification-Vendor": "ftbsc",
			"Specification-Version": "1", // We are version 1 of ourselves
			"Implementation-Title": project.name,
			"Implementation-Version": "${version}",
			"Implementation-Vendor" :"ftbsc",
			"Implementation-Timestamp": new Date().format("yyyy-MM-dd'T'HH:mm:ssZ")
		])
	}
}

jar.finalizedBy('reobfJar')

//copy jar from build/libs to the forge mod folder
tasks.register('deployJar', Copy) {
	if (!project.ext.deployJarDo.toBoolean()) return
	from project.jar
	into project.ext.deployJarTargetDir
}

publishing {
	publications {
		mavenJava(MavenPublication) {
			artifact jar
		}
	}
	repositories {
		maven {
			url "file:///${project.projectDir}/mcmodsrepo"
		}
	}
}

build {
	//dependsOn shadowJar, reobfShadowJar
	finalizedBy deployJar
}