bscv/build.gradle

plugins {
	id 'java'
	id 'eclipse'
	alias libs.plugins.forgeGradle;
	alias libs.plugins.gitVersion;
}

version          = gitVersion()
group            = 'ftbsc'
archivesBaseName = 'bscv'

def shortVersion = version.split('-')[0]

project.ext {
	deployJarDo          = getProjectProperty("deployJar.do", "false")
	deployJarTargetDir   = getProjectProperty("deployJar.targetDir", ".")
}

def getProjectProperty(String property, String fallback) { //allows for custom gradle.properties while retaining default fallback values
	return (project.hasProperty(property)) ? project.property(property) : fallback
}

java.toolchain.languageVersion = JavaLanguageVersion.of(8)

println('Java: ' + System.getProperty('java.version') + ' JVM: ' + System.getProperty('java.vm.version') + '(' + System.getProperty('java.vendor') + ') Arch: ' + System.getProperty('os.arch'))

minecraft {
	mappings channel: 'official', version: libs.versions.minecraft.get()
	accessTransformer = file('src/main/resources/META-INF/accesstransformer.cfg')
	runs {
		client {
			workingDirectory project.file('run')
			property 'forge.logging.markers', 'REGISTRIES'
			property 'forge.logging.console.level', 'debug'
			mods {
				bscv.source sourceSets.main
			}
		}
		data {
			workingDirectory project.file('run')
			property 'forge.logging.markers', 'REGISTRIES'
			property 'forge.logging.console.level', 'debug'
			args '--mod', 'bsvc', '--all', '--output', file('src/generated/resources/'), '--existing', file('src/main/resources/')
			mods {
				bscv.source sourceSets.main
			}
		}
	}
}

sourceSets.main.resources { srcDir 'src/generated/resources' }

repositories {
	mavenCentral()
	maven { url = 'https://maven.fantabos.co' }
}

dependencies {
	minecraft libs.minecraftForge
	implementation libs.lillero
	implementation libs.lilleroProcessor
	implementation libs.autoServiceAnnotations
	annotationProcessor libs.javaPoet
	annotationProcessor libs.lillero
	annotationProcessor libs.lilleroProcessor
	annotationProcessor libs.autoService
}

jar {
	archiveFileName = "${jar.archiveBaseName.get()}-${shortVersion}.${jar.archiveExtension.get()}"
	manifest {
		attributes([
			"Specification-Title": "bscv",
			"Specification-Vendor": "ftbsc",
			"Specification-Version": "1", // We are version 1 of ourselves
			"Implementation-Title": project.name,
			"Implementation-Version": project.version,
			"Implementation-Vendor" :"ftbsc",
			"Implementation-Timestamp": new Date().format("yyyy-MM-dd'T'HH:mm:ssZ")
		])
	}
}

jar.finalizedBy('reobfJar')

//copy jar from build/libs to the forge mod folder
tasks.register('deployJar', Copy) {
	if (!project.ext.deployJarDo.toBoolean()) return
	from project.jar
	into project.ext.deployJarTargetDir
}

build {
	finalizedBy deployJar
}