lillero-mapping-writer/build.gradle

plugins {
	id 'java'
	id 'com.palantir.git-version' version '0.13.0'
	id 'com.github.johnrengelman.shadow' version '7.1.2'
}

archivesBaseName = 'mapping-writer'
version = versionDetails().lastTag

java {
	sourceCompatibility = targetCompatibility = JavaVersion.VERSION_1_8
	withSourcesJar()
	withJavadocJar()
}

javadoc {
	options {
		links 'https://docs.zaaarf.foo/lillero-mapper/'
	}
}

repositories {
    mavenCentral()
	maven { url = 'https://maven.fantabos.co' }
}

dependencies {
	shadow(implementation 'commons-cli:commons-cli:1.5.0')
	shadow(implementation 'ftbsc.lll:mapper:0.4.1')
	implementation 'com.google.auto.service:auto-service-annotations:1.1.0'
	annotationProcessor 'com.google.auto.service:auto-service:1.1.0'
}

jar {
	manifest {
		attributes 'Main-Class': 'ftbsc.lll.mapper.writer.MappingWriter'
	}
}

shadowJar {
	archiveClassifier = ''
	dependencies {
		exclude(dependency('com.google.auto.service:auto-service-annotations:1.1.0'))
	}
}

build.dependsOn(shadowJar)